model
{
	Tau.noninformative <- 1.0E-4
	P.beta <- 1.0E+1
	P.gamma <- 1.0E-2
	for (i in 1:N.sector) {
		# plant abundance
		Abundance[i] ~ dpois(lambda[i])
		lambda[i] <- exp(a[1, Tr[i]] + x[1, i])
		# disturbance
		Disturbance[i] ~ dbin(p[i], N.dist)
		disturbance[i] ~ dbin(p[i], N.dist)
		logit(p[i]) <- a[2, Tr[i]] + x[2, i]
		# latent variable
		for (j in 1:2) {
			x[j, i] ~ dnorm(m[j, i], tau[j])
		}
		m[1, i] <- (
			(x[1, LeftRight[i, 1]] + x[1, LeftRight[i, 2]]) * (c[1] - 0.5)
			+ b[1] * (disturbance[i] - Mean.dist)
			+ b[2] * Gap[i]
			+ b[3] * Swamp[i]
		)
		m[2, i] <- (
			(x[2, LeftRight[i, 1]] + x[2, LeftRight[i, 2]]) * (c[2] - 0.5)
			+ b[4] * Distance[i]
			+ b[5] * Gap[i]
			+ b[6] * Swamp[i]
		)
	}
	# parameters
	for (k in 1:N.transect) {
		for (j in 1:2) {
			a[j, k] ~ dnorm(0, Tau.noninformative)
		}
	}
	for (j in 1:N.b) {
		b[j] ~ dnorm(0, Tau.noninformative)
	}
	for (j in 1:N.c) {
		c[j] ~ dbeta(P.beta, P.beta)
	}
	for (j in 1:2) {
		tau[j] ~ dgamma(P.gamma, P.gamma)
	}
}