model
{
	Tau.noninformative <- 1.0E-3
	Hyper.gamma <- 1.0E-2
	Tau.errD <- 100
	Tau.errH <- 100

	# Measurements
	for (i in 1:N.branches) { # branch
		# growth
		Bdiameter08[i] ~ dnorm(bdiameter08[i], Tau.errD)
		Bdiameter07[i] ~ dnorm(bdiameter07[i], Tau.errD)
		Bposition07[i] ~ dnorm(bposition07[i], Tau.errH)
		bdiameter08[i] <- exp(log.bdiameter08[i])
		bdiameter07[i] <- exp(log.bdiameter07[i])
		bposition07[i] <- exp(log.bposition07[i])
		# death
		Dead08[i] ~ dbern(prob[i])
		logit(prob[i]) <- logit.prob[i]
	}
	for (j in 1:N.trees) { # tree
		Height07[j] ~ dnorm(height07[j], Tau.errH)
		height07[j] <- exp(log.height07[j])
		#DeltaH[j] ~ dnorm(deltaH[j], Tau.errH)
		#deltaH[j] <- exp(log.deltaH[j])
	}

	# log RGR for each branch diameter (RE: random effects)
	for (i in 1:N.branches) {
		log.bdiameter08[i] <- log.bdiameter07[i] + log.rgr[i]
		log.rgr[i] ~ dnorm(mean.log.rgr[i], tau[1, Spc[i]]) # branch RE
		mean.log.rgr[i] <- (
			base.log.rgr.tree[Tree[i]]
			+ beta[1, Spc[i]] * (bposition07[i] - Mean.bposition07)
			+ beta[2, Spc[i]] * (log.bdiameter07[i] - Mean.log.diameter07)
		)
		log.bdiameter07[i] ~ dnorm(0.0, Tau.noninformative)
		log.bposition07[i] ~ dnorm(0.0, Tau.noninformative)
	}

	# blrt: base.log.rgr.tree for each tree
	for (j in 1:N.trees) {
		base.log.rgr.tree[j] ~ dnorm(mean.blrt[j], tau[2, SpcTr[j]]) # tree RE
		mean.blrt[j] <- (
			beta[3, SpcTr[j]]
			+ beta[4, SpcTr[j]] * (log.height07[j] - Mean.log.height07)
		)
		log.height07[j] ~ dnorm(0.0, Tau.noninformative)
	}

	# mortatlity: death rate
	for (i in 1:N.branches) {
		logit.prob[i] <- (
			base.logit.prob[Tree[i]]
			+ beta[5, Spc[i]] * (bposition07[i] - Mean.bposition07)
			+ beta[6, Spc[i]] * (log.bdiameter07[i] - Mean.log.diameter07)
		)
	}
	for (j in 1:N.trees) {
		base.logit.prob[j] ~ dnorm(mean.lp[j], tau[3, SpcTr[j]]) # tree RE
		mean.lp[j] <- (
			beta[7, SpcTr[j]]
			+ beta[8, SpcTr[j]] * (log.height07[j] - Mean.log.height07)
		)
	}

	# parameters --------------------------------------------------------------
	for (k in 1:N.beta) {
		for (kk in 1:N.spc) {
			beta[k, kk] ~ dnorm(0.0, Tau.noninformative)
		}
	}
	for (k in 1:N.tau) {
		for (kk in 1:N.spc) {
			tau[k, kk] ~ dgamma(Hyper.gamma, Hyper.gamma)
		}
	}
}