model
{
	Tau.noninformative <- 1.0E-4 # 無情報事前分布 (dnorm) の tau
	Hyper.gamma <- 1.0E-1 # 無情報事前分布 (dgamma) の rate
	Tau.err <- 10
	# 観測値との対応づけ
	for (i in 1:N.sample) {
		for (j in 1:4) {
			Leftover.a[i, j] ~ dnorm(leftover.a[i, j], Tau.err)
			leftover.a[i, j] <- Total.area - exp(log.a[i, j])
		}
	}

	# 「食欲」を plant A と H に分配する
	for (i in 1:N.sample) {
		for (j in 1:N.session) {
			log.a[i, j] <- log(p[i, j]) + log.req[i, j] # plant A
			log.a[i, j + 2] <- log(1 - p[i, j]) + log.req[i, j] # plant H
			logit(p[i, j]) <- logit.p[i, j]
			logit.p[i, j] ~ dnorm(mean.logit.p[i, j], tau[1]) # session 差
			mean.logit.p[i, j] <- (
				beta[1]
				+ beta[2] * HostH[i]
				+ beta[3] * SexM[i]
				+ random.i[i] # 個体差
				+ random.pop[Pop[i]] # 地域差
			) # 個体差が session 差と区別つかない?
			log.req[i, j] <- log(
				Total.area / (1 + exp(-logit.req[i, j]))
			)
			logit.req[i, j] ~ dnorm(0.0, Tau.noninformative)
		}
		random.i[i] ~ dnorm(0.0, tau[2]) # 個体差
	}

	# 係数 beta の値を事前分布から発生させる
	for (k in 1:N.beta) {
		beta[k] ~ dnorm(0.0, Tau.noninformative)
	}

	# 地域差の random effects を事前分布から発生させる
	for (k in 1:N.pop) {
		random.pop[k] ~ dnorm(0.0, tau[3])
	}

	# ばらつきパラメーター tau を超事前分布から発生させる
	for (k in 1:N.tau) {
		tau[k] ~ dgamma(Hyper.gamma, Hyper.gamma) # non-informative
	}
}