model
{
	Tau.noninformative <- 1.0E-3
	Hyper.gamma <- 1.0E-2
	# observation
	for (i in 1:N.sample) {
		Ws[i] ~ dnorm(ws[i], tau[1])
		Wr[i] ~ dnorm(wr[i], tau[1])
		log(wr[i]) <- log.wr[i]
		log(ws[i]) <- log.ws[i]
	}

	# mean values
	for (i in 1:N.sample) {
		# 1: weight allocation root vs shoot
		log.ws[i] <- log(a[i]) + log.w[i] # shoot
		log.wr[i] <- log(1.0 - a[i]) + log.w[i] # root
		logit(a[i]) <- logit.a[i]
		logit.a[i] ~ dnorm(mean.logit.a[i], tau[2])
		mean.logit.a[i] <- (
			beta[1]
			+ beta.f[1, Filter[i]] * Filter01[i]
			+ beta[2] * (log.w[i] - Mean.log.w)
			+ random.plot[Plot[i]]
		)
		log.w[i] ~ dnorm(0.0, Tau.noninformative)
	}

	# priors and hyper-priors
	for (k in 1:N.beta) {
		beta[k] ~ dnorm(0.0, Tau.noninformative)
	}

	# filter coefficients
	for (k in 1:N.beta.f) {
		beta.f[k, 1] ~ dnorm(0, 10) # dummy sampling for ``none'' filter
		for (kk in 2:N.filter) {
			beta.f[k, kk] ~ dnorm(0.0, Tau.noninformative)
		}
	}

	# random effects (plot)
	for (k in 1:N.plot) {
		random.plot[k] ~ dnorm(0.0, tau[3])
	}

	# tau
	for (k in 1:N.tau) {
		tau[k] ~ dgamma(Hyper.gamma, Hyper.gamma) # non-informative
	}
}