model
{
	Tau.noninformative <- 1.0E-2
	Hyper.gamma <- 1.0E-2

	# likelihood
	for (i in 1:N.sample) {
		Flower[i] ~ dbern(prob[i])
		logit(prob[i]) <- (
			(pbase[1] + pspc[1, Spc[i]])
			+ (pbase[2] + pspc[2, Spc[i]]) * LL2[i]
			+ (pbase[3] + pspc[3, Spc[i]]) * LL3[i]
			+ (pbase[4] + pspc[4, Spc[i]]) * LL4[i]
			+ (pbase[5] + pspc[5, Spc[i]]) * Log.Dbh[i]
			+ (pbase[6] + pspc[6, Spc[i]]) * fp[i]
			+ re.tree[Tree[i]]
			+ re.site[Site[i]]
			+ re.year[Year[i]]
		)
		fp[i] <- (1 - FpIsNa[i]) * Flower.prev[i] + FpIsNa[i] * fps[i]
		fps[i] ~ dbern(prob[i])
	}

	# tree effects
	for (k in 1:N.tree) {
		re.tree[k] ~ dnorm(0.0, tau[1])
	}

	# site effects
	for (k in 1:N.site) {
		re.site[k] ~ dnorm(0.0, tau[2])
	}

	# year effects
	for (k in 1:N.year) {
		re.year[k] ~ dnorm(0.0, tau[3])
	}

	# pbase and pspc
	for (j in 1:N.p) {
		pbase[j] ~ dnorm(0.0, Tau.noninformative)
	}
	for (j in 1:N.p) {
		for (k in 1:N.spc) {
			pspc[j, k] ~ dnorm(0.0, tau.pspc[j])
		}
	}

	# hyper priors
	for (j in 1:N.tau) {
		tau[j] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
	for (j in 1:N.p) {
		tau.pspc[j] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
}