model
{
	Tau.noninformative <- 1.0E-2
	Hyper.gamma <- 1.0E-2

	# likelihood
	for (i in 1:N.sample) {
		Flower[i] ~ dbern(prob[i])
		logit(prob[i]) <- (
			(pbase[1] + pspc[1, Spc[i]])
			+ (pbase[2] + pspc[2, Spc[i]]) * LL2[i]
			+ (pbase[3] + pspc[3, Spc[i]]) * LL3[i]
			+ (pbase[4] + pspc[4, Spc[i]]) * LL4[i]
			+ (pbase[5] + pspc[5, Spc[i]]) * Log.Dbh[i]
			+ re.tree[Tree[i]]
			+ re.ty[Tree[i], Year[i]]
			+ re.site[Site[i]]
		)
	}

	# tree effects
	for (t in 1:N.tree) {
		re.tree[t] ~ dnorm(0.0, tau[1])
		re.ty[t, 1] ~ dnorm(0.0, tau[2])
		for (y in 2:N.year) {
			re.ty[t, y] ~ dnorm(m[t, y], tau[3])
			m[t, y] <- (pbase[6] + pspc[6, TreeSpc[t]]) * re.ty[t, y - 1]
		}
	}

	# site effects
	for (k in 1:N.site) {
		re.site[k] ~ dnorm(0.0, tau[4])
	}

	# pbase and pspc
	for (j in 1:N.p) {
		pbase[j] ~ dnorm(0.0, Tau.noninformative)
	}
	for (j in 1:N.p) {
		for (k in 1:N.spc) {
			pspc[j, k] ~ dnorm(0.0, tau.pspc[j])
		}
	}

	# hyper priors
	for (j in 1:N.tau) {
		tau[j] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
	for (j in 1:N.p) {
		tau.pspc[j] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
}