model
{
	Tau.noninformative <- 1.0E-3
	Hyper.gamma <- 1.0E-2

	# ion concentration
	for (j in 1:N.ion) {
		ion[N.sample + 1, j] <- 0 # river head
		for (i in 1:N.sample) {
			ion[i, j] <- exp(log.ion[i, j])
		}
	}
	for (i in 1:N.sample) {
		for (j in 1:N.ion) {
			IonC[i, j] ~ dnorm(ionc[i, j], tau[1]) # observation
			ionc[i, j] <- exp(log.ion[i, j] - log(Wf[i]))
			log.ion[i, j] ~ dnorm(mean.log.ion[i, j], tau.ion[j, 3])
			mean.log.ion[i, j] <- log(ion[Upper[i], j] + d.ion[i, j])
			d.ion[i, j] <- D.wf[i] * exp(
				alpha[j]
				+ r.lulc[j, St[i]]
				+ beta2[j, Date[i]]
				+ beta3[j] * Sea[i]
			)
		}
	}
	for (j in 1:N.ion) {
		for (k in 1:N.st) {
			r.lulc[j, k] <- inprod(LuLc[k,], beta1[j,]) # !!!
		}
		for (k in 1:N.landtype) {
			beta1[j, k] ~ dnorm(0.0, tau.ion[j, 1])
		}
		for (k in 1:N.date) {
			beta2[j, k] ~ dnorm(0.0, tau.ion[j, 2])
		}
		for (k in 1:N.tau.ion) {
			tau.ion[j, k] ~ dgamma(Hyper.gamma, Hyper.gamma)
		}
		alpha[j] ~ dnorm(mean.alpha, tau[2])
		beta3[j] ~ dnorm(mean.beta3, tau[3]) # !!!
	}
	mean.alpha ~ dnorm(0.0, Tau.noninformative)
	mean.beta3 ~ dnorm(0.0, Tau.noninformative)

	# tau = 1 / variance
	for (k in 1:N.tau) {
		tau[k] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
}