model
{
	Tau.noninformative <- 1.0E-3
	Hyper.gamma <- 1.0E-2
	Tau.err.wf <- 1.0E-2

	# water flow
	wf[N.sample + 1] <- 0 # river head
	for (i in 1:N.sample) {
		LogWf[i] ~ dnorm(log.wf[i], tau[4]) # observation
		wf[i] <- exp(log.wf[i])
		log.wf[i] ~ dnorm(mean.log.wf[i], tau[1])
		mean.log.wf[i] <- log(wf[Upper[i]] + d.wf[i])
		d.wf[i] <- exp(log.d.wf[i])
		log.d.wf[i] ~ dnorm(mean.log.d.wf, tau[2])
	}
	mean.log.d.wf ~ dnorm(0.0, Tau.noninformative)

	# ion concentration
	for (j in 1:N.ion) {
		ion[N.sample + 1, j] <- 0 # river head
	}
	for (i in 1:N.sample) {
		for (j in 1:N.ion) {
			IonC[i, j] ~ dnorm(ionc[i, j], tau[3]) # observation
			ionc[i, j] <- ion[i, j] / wf[i]
			ion[i, j] <- exp(log.ion[i, j])
			log.ion[i, j] ~ dnorm(mean.log.ion[i, j], tau.li[j])
			mean.log.ion[i, j] <- log(ion[Upper[i], j] + d.ion[i, j])
			d.ion[i, j] <- exp(
				log.d.wf[i]
				+ alpha[j]
				+ inprod(LuLc[i,], beta1[j,])
				+ beta2[j, Date[i]]
			)
		}
	}
	for (j in 1:N.ion) {
		tau.li[j] ~ dgamma(Hyper.gamma, Hyper.gamma)
		alpha[j] ~ dnorm(0.0, Tau.noninformative)
		for (k in 1:N.landtype) {
			beta1[j, k] ~ dnorm(0.0, tau.beta[j, 1])
		}
		for (k in 1:N.date) {
			beta2[j, k] ~ dnorm(0.0, tau.beta[j, 2])
		}
		for (k in 1:N.beta) {
			tau.beta[j, k] ~ dgamma(Hyper.gamma, Hyper.gamma)
		}
	}

	# tau = 1 / variance
	for (k in 1:N.tau) {
		tau[k] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
}