model
{
	Tau.noninformative <- 5.0E-2
	P.gamma <- 1.0E-2
	P.beta <- 5
	# Observation
	for (i in 1:N.quad) {
		Total.mass[i] ~ dnorm(tm[i], tau[1])
		tm[i] <- pa[i, topj[i]] + m0L[i, topj[i]] + m0SF[i, topj[i]]
		topj[i] ~ dcat(alpha[i,])
		for (j in 1:N.sp) {
			MassL[i, j] ~ dnorm(mL[i, j], tau[2])
			MassSF[i, j] ~ dnorm(mSF[i, j], tau[2])
			mL[i, j] <- m[i, j] * fL[i, j] + m0L[i, j]
			mSF[i, j] <- m[i, j] * (1 - fL[i, j]) + m0SF[i, j]
			logit(fL[i, j]) <- (
				betaB[3] + betaS[3, j]
				+ (betaB[4] + betaS[4, j]) * Alt[i]
			)
			m[i, j] <- pa[i, j] * alpha[i, j]
			alpha[i, j] <- pa[i, j] / sum.pa[i]
			# m0L and m0SF
			m0L[i, j] <- fm0L[i, j] * MassEvergreen[i, j]
			m0SF[i, j] <- fm0SF[i, j] * MassTree[i, j]
			fm0L[i, j] ~ dbeta(P.beta, P.beta)
			fm0SF[i, j] ~ dbeta(P.beta, P.beta)
		}
	}
	# pa: Potential competitive ability
	for (i in 1:N.quad) {
		sum.pa[i] <- sum(pa[i,])
		for (j in 1:N.sp) {
			pa[i, j] <- exp(log.pa[i, j]) * Occurrence[i, j]
			log.pa[i, j] ~ dnorm(mlpa[i, j], tau[4])
			mlpa[i, j] <- (
				betaB[1] + betaS[1, j]
				+ (betaB[2] + betaS[2, j]) * Alt[i]
			)
		}
	}
	# Parameters and hyper parameters
	for (k in 1:N.betaB) {
		betaB[k] ~ dnorm(0, Tau.noninformative)
	}
	for (k in 1:N.betaS) {
		for (j in 1:N.sp) {
			betaS[k, j] ~ dnorm(0, tau.betaS[k])
		}
		tau.betaS[k] ~ dgamma(P.gamma, P.gamma)
	}
	for (k in 1:N.tau) {
		tau[k] ~ dgamma(P.gamma, P.gamma)
	}
}