model
{
	# Tau.noninformative = 1.0e-2,
	# Hyper.gamma = 1.0e-3
	for (i in 1:N.site) {
		# 1. Fish
		Fish1[i] ~ dcat(p.fish[i,])
		p.fish[i,1] <- p.fish.zero[i]
		p.fish[i,2] <- 1.0 - p.fish.zero[i]
		p.fish.zero[i] <- exp(-exp(log.fish.density[i]))
		log.fish.density[i] ~ dnorm(mu.log.fish.density[i], tau.delta[1])
		mu.log.fish.density[i] <- (
			beta.f[1]
			+ beta.f[2] * log.bzp.no.fish[i]
			+ beta.f[3] * w.temp[i]
			+ beta.f[4] * log.Area[i]
		)
		# 2. Bioamass zoo plankton
		BiomassZP[i] ~ dnorm(bzp[i], tau.err[1]) 
		bzp[i] <- exp(
			log.bzp.no.fish[i]
			+ beta.z[1] * log.fish.density[i]
			+ beta.z[2]
		)
		log.bzp.no.fish[i] ~ dnorm(mu.log.bzp.no.fish[i], tau.delta[2])
		mu.log.bzp.no.fish[i] <- (
			beta.z[3] * log.chl.a.no.zp[i]
			+ beta.z[4] * w.temp[i]
		)
		# 3. Chl-a, N, P
		log.chl.a[i] ~ dnorm(mu.log.chl.a[i], tau.delta[3])
		mu.log.chl.a[i] <- (
			log.chl.a.no.zp[i]
			+ beta.c[1] * log(bzp[i])
			+ beta.c[2]
		)
		log.chl.a.no.zp[i] ~ dnorm(mu.log.chl.a.no.zp[i], tau.delta[4])
		mu.log.chl.a.no.zp[i] <- (
			beta.c[3] * w.temp[i]
			+ beta.c[4] * log.din[i]
			+ beta.c[5] * log.dtp[i]
		)
		Chl.a[i] ~ dnorm(chl.a[i], tau.err[2])
		log(chl.a[i]) <- log.chl.a[i]
		# observation
		w.temp[i] ~ dnorm(W.temp[i], tau.err[3]) 
		log.din[i] ~ dnorm(log.DIN[i], tau.err[4])
		log.dtp[i] ~ dnorm(log.DTP[i], tau.err[5])
	}
	# parameters
	for (k in 1:N.beta.f) {
		beta.f[k] ~ dnorm(0, Tau.noninformative)
	}
	for (k in 1:N.beta.z) {
		beta.z[k] ~ dnorm(0, Tau.noninformative)
	}
	for (k in 1:N.beta.c) {
		beta.c[k] ~ dnorm(0, Tau.noninformative)
	}
	# hyper priors
	for (k in 1:N.err) {
		tau.err[k] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
	for (k in 1:N.delta) {
		tau.delta[k] ~ dgamma(Hyper.gamma, Hyper.gamma)
	}
}